Blockierende Methoden halten die Programmausführung an, bis sie vollständig abgeschlossen sind – während dieser Zeit werden keine anderen Aufgaben bearbeitet. Nicht blockierende Methoden hingegen ermöglichen es, mehrere Prozesse quasi gleichzeitig auszuführen, da sie den Ablauf nicht vollständig unterbrechen, sondern Aufgaben asynchron abarbeiten, beispielsweise durch zeitgesteuerte Überprüfungen.

code noch nicht getestet

In einer blockierenden Umsetzung wird delay() zum Blinken verwendet. Während der Wartezeit kann der mBot keine neuen Sensordaten auslesen. Dadurch kann er erst nach Ablauf der Verzögerung auf ein Hindernis reagieren, was in der Regel zu einem verspäteten Anhalten führt.

#include <MeMCore.h>

MeDCMotor motor1(M1);
MeDCMotor motor2(M2);
MeUltrasonicSensor ultrasonic(PORT_3); 
MeRGBLed led(0, 2);   
double limit = 15; // Grenze 15 cm

void setup() {
  led.setpin(13); 
}

void loop() {
  double distance = ultrasonic.distanceCm(); // Abstand messen

  if (distance > limit ) { // freie Fahrt?
    motor1.run(-255);
    motor2.run(255);
    
    // LEDs dauerhaft blinken, solange der mBot fährt
    led.setColor(0, 255, 0, 0);   // RGB-LED auf Rot setzen (LED 1)
    led.setColor(1, 255, 0, 0);   // RGB-LED auf Rot setzen (LED 2)
    led.show();
    delay(200);  // Blockiert den Code für 200 ms

    led.setColor(0, 0, 0, 0);     // RGB-LED ausschalten (LED 1)
    led.setColor(1, 0, 0, 0);     // RGB-LED ausschalten (LED 2)
    led.show();
    delay(200);  // Blockiert erneut für 200 ms
  }
  if(distance <= limit) { // stoppen ?
    motor1.run(0);
    motor2.run(0);
    
    // LEDs ausschalten
    led.setColor(0, 0, 0, 0);
    led.setColor(1, 0, 0, 0);
    led.show();
  }
}

In einer nicht-blockierenden Umsetzung wird die LED mit millis() gesteuert. Dadurch kann der mBot kontinuierlich Sensordaten auslesen und sofort stoppen, wenn er ein Hindernis erkennt, während die LED unabhängig weiterblinkt.

#include <MeMCore.h>

MeDCMotor motor1(M1);
MeDCMotor motor2(M2);
MeUltrasonicSensor ultrasonic(PORT_3);
MeRGBLed led(0, 2);

double limit = 15; // Grenze 15 cm

unsigned long previousMillis = 0;
bool ledState = false;
bool firstRun = true;

void setup() {
  led.setpin(13);
}

void loop() {
  double distance = ultrasonic.distanceCm(); // Abstand messen

  if (distance > limit ) { // freie Fahrt?
    motor1.run(255);
    motor2.run(-255);
    blinken(200);
  }
  if (distance <= limit) { // stoppen?
    motor1.run(0);
    motor2.run(0);
    // LEDs ausschalten, wenn der mBot stoppt
    led.setColor(0, 0, 0, 0);
    led.setColor(1, 0, 0, 0);
    led.show();
  }
}

void blinken(int interval) {
  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval || firstRun) {
    firstRun = false;
    previousMillis = currentMillis;
    ledState = !ledState;

    if (ledState) {
      led.setColor(0, 255, 0, 0);   // RGB-LED auf Rot setzen (LED 1)
      led.setColor(1, 255, 0, 0);   // RGB-LED auf Rot setzen (LED 2)
    } else {
      led.setColor(0, 0, 0, 0);     // RGB-LED ausschalten (LED 1)
      led.setColor(1, 0, 0, 0);     // RGB-LED ausschalten (LED 2)
    }
    led.show();
  }

}

Nicht-blockierende Methoden ermöglichen eine effizientere Steuerung des mBots, da Abläufe parallel ausgeführt werden können. Gleichzeitig sind blockierende Methoden einfacher umzusetzen und sind häufig ausreichend.

✅ Schnellere Reaktionszeit: Der Sensor wird kontinuierlich geprüft, sodass der mBot Hindernisse sofort erkennt und rechtzeitig anhalten kann, ohne durch Wartezeiten verzögert zu werden.

✅ Parallele Abläufe: Der mBot kann gleichzeitig fahren, blinken und Hindernisse erkennen, da keine Aufgabe den Programmfluss blockiert. Dadurch reagiert das System dynamischer auf Veränderungen in der Umgebung.

✅ Effizienter Code: Anstatt auf eine feste Wartezeit zu warten, werden Aufgaben zeitgesteuert verarbeitet. So bleibt das System jederzeit aktiv und reaktionsfähig.

✅ Einfache Umsetzung: Der Code ist leicht zu schreiben und zu verstehen, da Abläufe nacheinander ausgeführt werden, ohne komplexe Zeitsteuerung.

✅ In einfachen Anwendungen ausreichend: Wenn keine parallelen Abläufe oder schnelle Reaktionen erforderlich sind, kann die blockierende Methode eine pragmatische Lösung sein.